Tags:    delphi
Nu kan vi bevæge os væk fra væggen igen, hvis vi er kollideret mod den. Det kunne være sjovt, hvis vi også lavede en kollision detektor med vores kasse, men samtidig gjorde det muligt for os at hoppe op på den, og skubbe rundt med den. Til det vil vi bruge en lidt anden teknik. Hvis vi beregner afstanden fra kassens centrum og vores position kan vi faktisk afgøre om vi er kollideret mod den. Jeg har lavet en illustration set fra oven.



Som du kan se vil selve kollisionen foregå i en cirkel rundt omkring kassen, i stedet for selve kassen, men dette vil ikke kunne bemærkes når vi kollidere. På denne måde vil vi nemlig også let kunne finde ud af om vi rammer kassen, hvis vi vil hoppe op på den. Ud over det, deler vi vores hop i følgende stadier: JumpStart, JumpUp og JumpDown. Illustrationen nedenunder illustrere dtte:



Ideen er at JumpStart skal indeholde Y position når vi påbegynder vores hop. JumpUp er fortæller at vi er på vej op i vores hop. JumpDown fortæller om vi er på vej ned fra vores fra hop. Hvis vi er på vej ned og vores position er er højere end kassens højde, og vi samtidig vil kollidere mod kassen betyder det, at vi rammer kassen, ellers rammer vi gulvet. Da vores kasse skal være i stand til at blive flyttet tilføjer vi en global variant: KassePosition, som en TVector og implementere KassePosition i kassens matrix i FormPaint proceduren. KassePositionen vil samtidig være kasses centrum!

procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor(0,0,0,0);
  glClear(gl_Color_Buffer_Bit or gl_Depth_Buffer_Bit);

  glEnable(gl_Depth_Test);

  glEnable(gl_Normalize);

  glEnable(gl_Color_Material);

  glPushMatrix;

  with Rotation do
  begin
    glRotatef(X,1,0,0);
    glRotatef(Y,0,1,0);
    glRotatef(Z,0,0,1);
  end;

  with Translation do
  glTranslatef(X,Y-5,Z);

  glLightfv(gl_Light0, gl_Ambient, @LysAmbient);
  glLightfv(gl_Light0, gl_Diffuse, @LysDiffuse);
  glLightfv(gl_Light0, gl_Specular, @LysSpecular);
  glLightfv(gl_Light0, gl_Position, @LysPosition);
  glEnable(gl_Light0);

  glDisable(gl_Lighting);
  glDisable(gl_Texture_2D);

  glPointSize(4);
  glBegin(gl_Points);
    glVertex3fv(@LysPosition);
  glEnd;

  glEnable(gl_Lighting);
  glEnable(gl_Texture_2D);

  //Aktivere mit gulv texture
  glBindTexture(gl_Texture_2D, Gulv_ID);

  //Tegner mit gulv
  glBegin(gl_Quads);
    //Normal for gulvet (Peger lodret op!)
    glNormal3f(0, 1, 0);
    glTexCoord2f(0,4);
    glVertex3f(-50, -3, -50);
    glTexCoord2f(0,0);
    glVertex3f(-50, -3, +50);
    glTexCoord2f(4,0);
    glVertex3f(+50, -3, +50);
    glTexCoord2f(4,4);
    glVertex3f(+50, -3, -50);
  glEnd;

  //Aktivere mit væg texture
  glBindTexture(gl_Texture_2D, Vaeg_ID);

  //Tegner min væg
  glBegin(gl_Quads);
    glNormal3f(0,0,1);
    glTexCoord2f(0,1);
    glVertex3f(-50, -3, -50);
    glTexCoord2f(0,0);
    glVertex3f(-50, +22, -50);
    glTexCoord2f(4,0);
    glVertex3f(+50, +22, -50);
    glTexCoord2f(4,1);
    glVertex3f(+50, -3, -50);
  glEnd;

  //Aktivere kassens texture med Loft_ID
  glBindTexture(gl_Texture_2D, Loft_ID);

  //Begynder på kassens matrix
  glPushMatrix;

    //Flytter kassen!
    with KassePosition do
    glTranslatef(X, Y, Z);

    //Definere vores kasse
    glBegin(gl_Quads);

      // 1) normal. (Peger mod dig!)
      glNormal3f( 0, 0, 1);
      //Koordinater for første side (Forside)
      glTexCoord2f(0, 0); glVertex3f(-3, -3,  3);
      glTexCoord2f(1, 0); glVertex3f( 3, -3,  3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3,  3);
      glTexCoord2f(0, 1); glVertex3f(-3,  3,  3);

      // 3) normal (Peger væk fra dig!)
      glNormal3f( 0, 0,-1);
      //Koordinater for anden side (Bagsiden)
      glTexCoord2f(1, 0); glVertex3f(-3, -3, -3);
      glTexCoord2f(1, 1); glVertex3f(-3,  3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3,  3, -3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3, -3);

      // 3) normal
      glNormal3f( 0, 1, 0);
      //Koordinater for tredje siden (Toppen)
      glTexCoord2f(0, 1); glVertex3f(-3,  3, -3);
      glTexCoord2f(0, 0); glVertex3f(-3,  3,  3);
      glTexCoord2f(1, 0); glVertex3f( 3,  3,  3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3, -3);

      // 4) normal
      glNormal3f( 0,-1, 0);
      //Koordinater for fjerde side (Bunden)
      glTexCoord2f(1, 1); glVertex3f(-3, -3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3, -3, -3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3,  3);
      glTexCoord2f(1, 0); glVertex3f(-3, -3,  3);

      // 5) normal
      glNormal3f( 1, 0, 0);
      //Koordinater for femte side (Højre)
      glTexCoord2f(1, 0); glVertex3f( 3, -3, -3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3,  3,  3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3,  3);

      // 6) normal
      glNormal3f(-1, 0, 0);
      //Koordinater for sjette side (Venstre)
      glTexCoord2f(0, 0); glVertex3f(-3, -3, -3);
      glTexCoord2f(1, 0); glVertex3f(-3, -3,  3);
      glTexCoord2f(1, 1); glVertex3f(-3,  3,  3);
      glTexCoord2f(0, 1); glVertex3f(-3,  3, -3);
    glEnd;

  //Afslutter kassens matrix
  glPopMatrix;

  glPopMatrix;

  SwapBuffers(Context.DeviceContext);
end;

Koden til kollision detektoren for kassen i Idle proceduren, vil blive ret lang. Jeg har derfor valgt at kommentere den undervejs.

var
  FPS, I : Integer;
  JumpUp, JumpDown, KasseKollision, MoveForward, MoveBackward : Boolean;
  JumpHeight : Single = -5;
  JumpStart : Single;
  Gravity : Single = 0.2;
  Speed : Single = 0.4;
procedure TForm1.Idle(Sender : TObject; var Done : Boolean);
var
  P : TPoint;
  S, X, Z : Single;
begin
  Done := False;

//----------------------------------------------------------------------------
//  Dreje Camera rundt med musen
//----------------------------------------------------------------------------

  //Modtage cursorens position
  GetCursorPos(P);
  //Beregener
  P.X := (Left+(Width div 2))-P.X;
  P.Y := (Top+(Height div 2))-P.Y;
  //Rotere
  Rotation.Y := Rotation.Y-(P.X*0.1);
  Rotation.X := Rotation.X-(P.Y*0.1);
  //Saetter vores cursor til vores forms centrum
  SetCursorPos(Left+(Width div 2),Top+(Height div 2));

//----------------------------------------------------------------------------
//  Kollision
//----------------------------------------------------------------------------

  //Simulere et skridt fremad
  if MoveForward then
  begin
    X := Translation.X-(Sin(DegToRad(Rotation.Y))*Speed);
    Z := Translation.Z+(Cos(DegToRad(Rotation.Y))*Speed);
  end
  else
    //Simulere et skridt tilbage
    if MoveBackward then
    begin
      X := Translation.X+(Sin(DegToRad(Rotation.Y))*Speed);
      Z := Translation.Z-(Cos(DegToRad(Rotation.Y))*Speed);
    end
    else
      //Står stille
      begin
        X := Translation.X;
        Z := Translation.Z;
      end;

  //Udregner afstanden mellem vores position og kassens centrum
  S := Sqrt(Power((-X)-KassePosition.X,2)+Power((-Z)-KassePosition.Z,2));

  //Hvis afstanden mellem vores position og kassens centrum er mindre end 4 uints,
  //betyder det at vi skal foretag en kollision detektion mod kassen!
  if S < 4 then
  KasseKollision := True
  else
    KasseKollision := False;

  //Hopper op i luften
  if JumpUp then
  begin
    //Hvis vi er under den højeste mulige position som vores hop tillader os,
    //bliver vi trukket op ad
    if JumpHeight+JumpStart < Translation.Y then
    Translation.Y := Translation.Y-Gravity
    else
      //Vi er så højt oppe i luften som vores hop har tilladt os,
      //forbereder os derfor til at falde ned ad igen
      begin
        //Præcisere vores position
        Translation.Y := JumpHeight+JumpStart;
        //Notere at vi er faerdig med at hoppe op ad
        JumpUp := False;
        //Notere at vi er klar til at falde ned igen
        JumpDown := True;
      end;
  end
  else
    begin
      //Hvis vi er i berøring af kassen
      if KasseKollision then
      begin
        //Hvis vi befinder os over kassen
        if Translation.Y <= -4.75 then
        begin
          //Hvis vi befinder os over kassens højde,
          //bliver vi trukket ned ad
          if Translation.Y < -5 then
          Translation.Y := Translation.Y+Gravity
          else
            begin
              //præcisere vores position
              Translation.Y := -5;
              //Notere at vi er landet og er klar til at hoppe igen
              JumpDown := False;
            end;
        end
        //Hvis vi befinder os ved siden af kassen
        else
          //Hvis vi befinder os over gulvet,
          //bliver vi trukket ned ad
          if Translation.Y < 0 then
          Translation.Y := Translation.Y+Gravity
          else
            begin
              //praecisere vores position
              Translation.Y := 0;
              //Notere at vi er landet og er klar til at hoppe igen
              JumpDown := False;
            end;
      end
      //Ingen berørelse af kassen
      else
        //Hvis vi befinder os over gulvet,
        //bliver vi trukket ned ad
        if Translation.Y < JumpStart then
        Translation.Y := Translation.Y+Gravity
        else
          begin
            //præcisere vores position
            Translation.Y := 0;
            //Notere at vi er landet og er klar til at hoppe igen
            JumpDown := False;
          end;
    end;

  //Væg kollision
  if Kollision(-50,-48,+50,-48,-X,-Z) then

  //Kasse Kollision
  if KasseKollision then
  begin
    //Hvis vi står på kassen skal vi bevæge os som gik vi rundt på gulvet
    if Translation.Y = JumpHeight then
    begin
      Translation.X := X;
      Translation.Z := Z;
    end
    else
      //Hvis ikke vi hopper kan vi skubbe kassen langs gulvet
      if not JumpUp and not JumpDown then
      begin
        //Vi skubber kassen fremad (Står med front mod kassen)
        if MoveForward then
        begin
          //Flytter os selv
          Translation.X := Translation.X-(Sin(DegToRad(Rotation.Y))*(Speed * 0.1));
          Translation.Z := Translation.Z+(Cos(DegToRad(Rotation.Y))*(Speed * 0.1));
          //Flytter kassen
          KassePosition.X := KassePosition.X+(Sin(DegToRad(Rotation.Y))*(Speed * 0.1));
          KassePosition.Z := KassePosition.Z-(Cos(DegToRad(Rotation.Y))*(Speed * 0.1));
        end;
        //Vi skubber kassen, mens vi går tilbage (Står med ryggen til kassen)
        if MoveBackWard then
        begin
          //Flytter os selv
          Translation.X := Translation.X+(Sin(DegToRad(Rotation.Y))*(Speed * 0.1));
          Translation.Z := Translation.Z-(Cos(DegToRad(Rotation.Y))*(Speed * 0.1));
          //Flytter kassen
          KassePosition.X := KassePosition.X-(Sin(DegToRad(Rotation.Y))*(Speed * 0.1));
          KassePosition.Z := KassePosition.Z+(Cos(DegToRad(Rotation.Y))*(Speed * 0.1));
        end;
      end;
  end
  else
    //Ingen kollision
    begin
      //Ingen kollision mod kassen, betyder at vi vil kunne flytte os rundt normalt
      Translation.X := X;
      Translation.Z := Z;
    end;

  FormPaint(nil);
  Caption := IntToStr(FPS);
  Inc(I);
end;

Som du kan se, har jeg yderligere defineret to varianter: Speed (Fart) og Gravity (Tyngdekraft), som Single. Så er det lettere for dig at tilpasse koden, hvis du hellere vil havde en anden resultat af effekten. Til sidst skal vi huske at give JumpStart en værdi inden vi starter med at hoppe. Det vil derfor blive i vores FormKeyDown procedure.

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of
    vk_Space:  if not JumpUp and not JumpDown then
               begin
                 JumpStart := Translation.Y;
                 JumpUp := True;
               end;
    vk_Escape: Close;
    end; //Case
end;

Kassen er skubbet hen i nærheden af lyskilden


Står oven på kassen og kigger ned

Prøv nu at skubbe kassen i nærheden af lyskilden. Du skulle gerne se, at shadingen på kassens sider ændres i takt med at afstand til lyset ændres. Du kan yderligere hoppe op på kassen og hoppe ned på gulvet igen.

Det var alt for denne fem-og-tyve-øre. Jeg håber I kunne lide min artikel. Nu skulle I faktisk være i stand til at kunne lave jeres helt eget spil. Der er dog stadig mange ting der mangler at blive fortalt, men det kan være at der dukker en ny artikel op engang i fremtiden! Jeg vil tilbage til mine studier og forberede mig til mine eksamener - for hvem ved, måske en eller anden dag BLIVER jeg rent faktisk færdig med min uddannelse som "Computer Games Designer", og måske tager jeg hjem til danmark igen og bruger verdens bedste sprog - DANSK ) Mine sidste ord vil blive.


Held og Lykke
Søren Klit Lambæk
University of Teesside, Middlesbrough, UK

PS: Endnu engang vil jeg lige nævne at der findes yderlige tutorials på mit site: http://www.opengl-delphi.dk

Hvad synes du om denne artikel? Giv din mening til kende ved at stemme via pilene til venstre og/eller lægge en kommentar herunder.

Del også gerne artiklen med dine Facebook venner:  

Karma barometer (30 dage)

IT jobs | Kontakt | Om Udvikleren.dk | Om karma | IT nyheds arkiv | Annoncering

X